alice.pds.demo.boltless.dev
This repository has no description
23 kB
668 lines
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-26.05";
6 microvm = {
7 url = "github:microvm-nix/microvm.nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 fenix = {
11 url = "github:nix-community/fenix";
12 inputs.nixpkgs.follows = "nixpkgs";
13 };
14 gomod2nix = {
15 url = "github:nix-community/gomod2nix";
16 inputs.nixpkgs.follows = "nixpkgs";
17 };
18 flake-compat = {
19 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
20 flake = false;
21 };
22 indigo = {
23 url = "github:oppiliappan/indigo";
24 flake = false;
25 };
26 htmx-src = {
27 url = "https://cdn.jsdelivr.net/npm/htmx.org@2.0.10/dist/htmx.min.js";
28 flake = false;
29 };
30 htmx-ws-src = {
31 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.4";
32 flake = false;
33 };
34 lucide-src = {
35 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
36 flake = false;
37 };
38 inter-fonts-src = {
39 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
40 flake = false;
41 };
42 actor-typeahead-src = {
43 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
44 flake = false;
45 };
46 mermaid-src = {
47 url = "https://cdn.jsdelivr.net/npm/mermaid@11.12.3/dist/mermaid.min.js";
48 flake = false;
49 };
50 hls-src = {
51 url = "https://cdn.jsdelivr.net/npm/hls.js@1.5.13/dist/hls.min.js";
52 flake = false;
53 };
54 mathjax-src = {
55 url = "https://cdn.jsdelivr.net/npm/mathjax@4.1.2/tex-svg.js";
56 flake = false;
57 };
58 tailwindcss-animated-src = {
59 url = "https://registry.npmjs.org/tailwindcss-animated/-/tailwindcss-animated-1.1.2.tgz";
60 flake = false;
61 };
62 ibm-plex-mono-src = {
63 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
64 flake = false;
65 };
66 sqlite-lib-src = {
67 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
68 flake = false;
69 };
70 fetch-tangled = {
71 url = "git+https://tangled.org/isabelroses.com/fetch-tangled";
72 inputs.nixpkgs.follows = "nixpkgs";
73 };
74 };
75
76 outputs = {
77 self,
78 nixpkgs,
79 fenix,
80 gomod2nix,
81 indigo,
82 htmx-src,
83 htmx-ws-src,
84 lucide-src,
85 inter-fonts-src,
86 sqlite-lib-src,
87 ibm-plex-mono-src,
88 actor-typeahead-src,
89 mermaid-src,
90 hls-src,
91 microvm,
92 fetch-tangled,
93 mathjax-src,
94 tailwindcss-animated-src,
95 ...
96 }: let
97 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
98 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
99 nixpkgsFor = forAllSystems (system:
100 import nixpkgs {
101 inherit system;
102 overlays = [fetch-tangled.overlays.default];
103 });
104
105 mkPackageSet = pkgs:
106 pkgs.lib.makeScope pkgs.newScope (self: {
107 src = let
108 fs = pkgs.lib.fileset;
109 in
110 fs.toSource {
111 root = ./.;
112 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
113 };
114 rustSrc = let
115 fs = pkgs.lib.fileset;
116 in
117 fs.toSource {
118 root = ./.;
119 fileset =
120 fs.intersection
121 (fs.fromSource self.src)
122 (fs.unions [
123 ./Cargo.toml
124 ./Cargo.lock
125 ./lexicons
126 ./shuttle
127 ./bobbin
128 ./knot2
129 ]);
130 };
131 buildGoApplication =
132 (self.callPackage "${gomod2nix}/builder" {
133 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
134 }).buildGoApplication;
135 rustPlatform = pkgs.makeRustPlatform {
136 inherit (fenix.packages.${pkgs.stdenv.hostPlatform.system}.stable) rustc cargo;
137 };
138 rustPlatformStatic = let
139 system = pkgs.stdenv.hostPlatform.system;
140 muslTarget = pkgs.pkgsStatic.stdenv.hostPlatform.rust.rustcTarget;
141 toolchain = fenix.packages.${system}.combine [
142 fenix.packages.${system}.stable.cargo
143 fenix.packages.${system}.stable.rustc
144 fenix.packages.${system}.targets.${muslTarget}.stable.rust-std
145 ];
146 in
147 pkgs.pkgsStatic.makeRustPlatform {
148 cargo = toolchain;
149 rustc = toolchain;
150 };
151 modules = ./nix/gomod2nix.toml;
152 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
153 inherit sqlite-lib-src;
154 };
155 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
156 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
157 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
158 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src mermaid-src hls-src mathjax-src tailwindcss-animated-src;
159 };
160 web-static-files = self.callPackage ./nix/pkgs/web-static-files.nix {
161 inherit inter-fonts-src ibm-plex-mono-src;
162 };
163 appview = self.callPackage ./nix/pkgs/appview.nix {};
164 blog = self.callPackage ./nix/pkgs/blog.nix {};
165 docs = self.callPackage ./nix/pkgs/docs.nix {
166 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
167 inherit (pkgs) pagefind;
168 };
169 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
170 shuttle = self.callPackage ./nix/pkgs/shuttle.nix {
171 src = self.rustSrc;
172 };
173 shuttle-static = self.callPackage ./nix/pkgs/shuttle.nix {
174 src = self.rustSrc;
175 rustPlatform = self.rustPlatformStatic;
176 };
177 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
178 knot = self.callPackage ./nix/pkgs/knot.nix {};
179 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
180 tap = self.callPackage ./nix/pkgs/tap.nix {};
181 knotmirror = self.callPackage ./nix/pkgs/knotmirror.nix {};
182 bobbin = self.callPackage ./nix/pkgs/bobbin.nix {};
183 zoekt-webserver = self.callPackage ./nix/pkgs/zoekt-webserver.nix {};
184 zoekt-tngl-indexserver = self.callPackage ./nix/pkgs/zoekt-tngl-indexserver.nix {};
185 });
186 in {
187 overlays.default = final: prev: {
188 inherit
189 (mkPackageSet final)
190 lexgen
191 goat
192 sqlite-lib
193 spindle
194 shuttle
195 knot-unwrapped
196 knot
197 appview
198 docs
199 dolly
200 tap
201 knotmirror
202 bobbin
203 zoekt-webserver
204 zoekt-tngl-indexserver
205 ;
206 };
207
208 packages = forAllSystems (system: let
209 pkgs = nixpkgsFor.${system};
210 linuxPkgs = nixpkgsFor."x86_64-linux";
211 packages = mkPackageSet pkgs;
212 staticPackages = mkPackageSet pkgs.pkgsStatic;
213 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
214 in {
215 inherit
216 (packages)
217 appview
218 appview-static-files
219 web-static-files
220 blog
221 lexgen
222 goat
223 spindle
224 knot
225 knot-unwrapped
226 sqlite-lib
227 docs
228 shuttle
229 shuttle-static
230 dolly
231 tap
232 knotmirror
233 bobbin
234 zoekt-webserver
235 zoekt-tngl-indexserver
236 ;
237
238 pkgsStatic-appview = staticPackages.appview;
239 pkgsStatic-knot = staticPackages.knot;
240 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
241 pkgsStatic-spindle = staticPackages.spindle;
242 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
243 pkgsStatic-dolly = staticPackages.dolly;
244
245 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
246 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
247 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
248 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
249 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
250
251 treefmt-wrapper = pkgs.treefmt.withConfig {
252 settings.formatter = {
253 alejandra = {
254 command = pkgs.lib.getExe pkgs.alejandra;
255 includes = ["*.nix"];
256 };
257
258 gofmt = {
259 command = pkgs.lib.getExe' pkgs.go "gofmt";
260 options = ["-w"];
261 includes = ["*.go"];
262 };
263
264 rustfmt = {
265 command = pkgs.lib.getExe' fenix.packages.${system}.stable.rustfmt "rustfmt";
266 options = ["--edition" "2024"];
267 includes = ["*.rs"];
268 excludes = ["**/src/_lex/**"];
269 };
270
271 prettier = {
272 command = pkgs.writeShellScript "prettier-wrapper" ''
273 cd web
274 args=()
275 for arg in "$@"; do
276 if [[ "$arg" == web/* ]]; then
277 args+=("''${arg#web/}")
278 else
279 args+=("$arg")
280 fi
281 done
282 exec ${pkgs.lib.getExe pkgs.prettier} "''${args[@]}"
283 '';
284 options = ["-w"];
285 includes = [
286 "web/**/*.cjs"
287 "web/**/*.css"
288 "web/**/*.html"
289 "web/**/*.js"
290 "web/**/*.json"
291 "web/**/*.json5"
292 "web/**/*.jsx"
293 "web/**/*.mdx"
294 "web/**/*.mjs"
295 "web/**/*.scss"
296 "web/**/*.ts"
297 "web/**/*.tsx"
298 "web/**/*.vue"
299 "web/**/*.yaml"
300 "web/**/*.yml"
301 ];
302 excludes = [
303 "web/static/**"
304 "web/src/lib/api/lexicons/**"
305 ];
306 };
307 };
308 };
309
310 spindle-nixos-image = linuxPkgs.callPackage ./nix/pkgs/spindle-nixos-image.nix {
311 nixosSystem = self.nixosConfigurations.spindle-nixos;
312 };
313 spindle-nixos-image-tarball = linuxPkgs.runCommand "spindle-nixos-image-tarball.tar.gz" {} ''
314 tar -S -C ${self.packages.${system}.spindle-nixos-image} -h -czf $out .
315 '';
316
317 spindle-alpine-image = let
318 branch = "3.24";
319 version = "${branch}.0";
320 arch = "x86_64";
321 cdn = "https://dl-cdn.alpinelinux.org/alpine/v${branch}/releases/${arch}";
322
323 shuttle = (mkPackageSet linuxPkgs).shuttle-static;
324 in
325 linuxPkgs.callPackage ./nix/pkgs/spindle-alpine-image.nix {
326 inherit arch shuttle;
327 repositories = [
328 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/main"
329 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/community"
330 ];
331 rootfs = linuxPkgs.fetchurl {
332 url = "${cdn}/alpine-minirootfs-${version}-${arch}.tar.gz";
333 hash = "sha256-3poRwODn6clNs+2K97RQ6vwLE2h71+kZnVUFDyCqCok=";
334 };
335 kernel = linuxPkgs.fetchurl {
336 url = "${cdn}/netboot-${version}/vmlinuz-virt";
337 hash = "sha256-Hmv5Ancgx1w+0NeRcfIbV5HuQMqXldB8fG4E3F6irpA=";
338 };
339 initramfs = linuxPkgs.fetchurl {
340 url = "${cdn}/netboot-${version}/initramfs-virt";
341 hash = "sha256-ZCWGSaVMOYOmLz1Gwsf2RhYarMqk+tFVA6MMDWiHVJQ=";
342 };
343 modloop = linuxPkgs.fetchurl {
344 url = "${cdn}/netboot-${version}/modloop-virt";
345 hash = "sha256-p3yO7yU28k04iT01sOzhDmEYi+Yl7VZs5r3RYsWCBX0=";
346 };
347 };
348 spindle-alpine-image-tarball = linuxPkgs.runCommand "spindle-alpine-image-tarball.tar.gz" {} ''
349 tar -S -C ${self.packages.${system}.spindle-alpine-image} -h -czf $out .
350 '';
351 });
352 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
353 devShells = forAllSystems (system: let
354 pkgs = nixpkgsFor.${system};
355 packages' = self.packages.${system};
356 tailwindcss-plugins = pkgs.linkFarm "tailwindcss-plugins" [
357 {
358 name = "tailwindcss-animated";
359 path = tailwindcss-animated-src;
360 }
361 ];
362 staticShell = args:
363 (pkgs.mkShell.override {
364 stdenv = pkgs.pkgsStatic.stdenv;
365 }) (args
366 // {
367 nativeBuildInputs =
368 args.nativeBuildInputs
369 ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [
370 pkgs.darwin.cctools
371 ];
372 });
373 in {
374 default = staticShell {
375 nativeBuildInputs =
376 [
377 pkgs.go
378 pkgs.air
379 pkgs.gopls
380 pkgs.httpie
381 pkgs.litecli
382 pkgs.websocat
383 pkgs.tailwindcss
384 pkgs.nixos-shell
385 pkgs.redis
386 pkgs.worker-build
387 pkgs.cargo-generate
388 pkgs.qemu
389 pkgs.cdrkit
390 pkgs.buf
391 pkgs.protobuf
392 pkgs.protoc-gen-prost
393 pkgs.protoc-gen-prost-crate
394 pkgs.protoc-gen-prost-serde
395 pkgs.protoc-gen-go
396 (fenix.packages.${system}.combine [
397 fenix.packages.${system}.stable.cargo
398 fenix.packages.${system}.stable.rustc
399 fenix.packages.${system}.stable.rust-src
400 fenix.packages.${system}.stable.clippy
401 fenix.packages.${system}.stable.rustfmt
402 fenix.packages.${system}.targets.wasm32-unknown-unknown.stable.rust-std
403 ])
404 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
405 packages'.lexgen
406 packages'.treefmt-wrapper
407 packages'.tap
408 pkgs.e2fsprogs
409 pkgs.util-linux
410 pkgs.pnpm
411 pkgs.nodejs
412 ]
413 ++ pkgs.lib.optionals pkgs.stdenv.isLinux [
414 pkgs.parted
415 pkgs.slirp4netns
416 pkgs.iproute2
417 ];
418 shellHook = ''
419 export CC=${pkgs.stdenv.cc}/bin/cc
420 export NODE_PATH=${tailwindcss-plugins}''${NODE_PATH:+:$NODE_PATH}
421 (
422 cd "$(git rev-parse --show-toplevel 2>/dev/null || pwd)"
423 mkdir -p appview/pages/static
424 # temporary self-heal for workspaces that copied static assets as read-only
425 [ -d appview/pages/static/icons ] && [ ! -w appview/pages/static/icons ] && chmod -R u+rwX appview/pages/static
426 # no preserve is needed because watch-tailwind will want to be able to overwrite
427 cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
428 mkdir -p web/static
429 rm -rf web/static/fonts web/static/logos
430 cp -fr --no-preserve=ownership,mode ${packages'.web-static-files}/* web/static
431 )
432 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
433 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
434 # Make xcrun (Nix stub) able to find ld from the system Command Line Tools.
435 # Without this, worker-build/cargo fails with "error: tool 'ld' not found".
436 if [ -d /Library/Developer/CommandLineTools/usr/bin ]; then
437 export PATH=/Library/Developer/CommandLineTools/usr/bin:$PATH
438 fi
439 '';
440 env.CGO_ENABLED = 1;
441 };
442 });
443 apps = forAllSystems (system: let
444 pkgs = nixpkgsFor."${system}";
445 packages' = self.packages.${system};
446 tailwindcss-plugins = pkgs.linkFarm "tailwindcss-plugins" [
447 {
448 name = "tailwindcss-animated";
449 path = tailwindcss-animated-src;
450 }
451 ];
452 air-watcher = name: arg:
453 pkgs.writeShellScriptBin "run"
454 ''
455 export PATH=${pkgs.go}/bin:$PATH
456 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
457 -build.args_bin "${arg}"
458 '';
459 tailwind-watcher =
460 pkgs.writeShellScriptBin "run"
461 ''
462 export BROWSERSLIST_IGNORE_OLD_DATA=true
463 export NODE_PATH=${tailwindcss-plugins}
464 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
465 '';
466 in {
467 watch-appview = {
468 type = "app";
469 program = toString (pkgs.writeShellScript "watch-appview" ''
470 echo "copying static files to appview/pages/static..."
471 mkdir -p appview/pages/static
472 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
473 ${air-watcher "appview" ""}/bin/run
474 '');
475 };
476 watch-knot = {
477 type = "app";
478 program = ''${air-watcher "knot" "server"}/bin/run'';
479 };
480 watch-spindle = {
481 type = "app";
482 program = ''${air-watcher "spindle" ""}/bin/run'';
483 };
484 watch-blog = {
485 type = "app";
486 program = toString (pkgs.writeShellScript "watch-blog" ''
487 echo "copying static files to appview/pages/static..."
488 mkdir -p appview/pages/static
489 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
490 ${air-watcher "blog" "serve"}/bin/run
491 '');
492 };
493 watch-tailwind = {
494 type = "app";
495 program = ''${tailwind-watcher}/bin/run'';
496 };
497 serve-docs = {
498 type = "app";
499 program = toString (pkgs.writeShellScript "serve-docs" ''
500 echo "building docs..."
501 docsOut=$(nix build --no-link --print-out-paths .#docs)
502 echo "serving docs at http://localhost:1414"
503 cd "$docsOut"
504 exec ${pkgs.python3}/bin/python3 -m http.server 1414
505 '');
506 };
507 regenerate-proto = {
508 type = "app";
509 program =
510 (pkgs.writeShellApplication {
511 name = "regenerate-proto";
512 runtimeInputs = with pkgs; [git buf coreutils];
513 text = ''
514 rootDir=$(git rev-parse --show-toplevel 2>/dev/null || pwd)
515 cd "$rootDir"
516 echo ">>> regenerating protobuf files.."
517 buf generate
518 echo ">>> generating file descriptor set for shuttle..."
519 buf build -o shuttle/src/gen/file_descriptor_set.bin
520 echo ">>> done"
521 '';
522 })
523 + "/bin/regenerate-proto";
524 };
525 vm = let
526 guestSystem =
527 if pkgs.stdenv.hostPlatform.isAarch64
528 then "aarch64-linux"
529 else "x86_64-linux";
530 in {
531 type = "app";
532 program =
533 (pkgs.writeShellApplication {
534 name = "launch-vm";
535 text = ''
536 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
537 cd "$rootDir"
538
539 # Reset TMPDIR in case it points to a stale nix-shell temp dir
540 export TMPDIR=/tmp
541
542 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
543
544 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
545 exec ${pkgs.lib.getExe
546 (import ./nix/vm.nix {
547 inherit nixpkgs self;
548 system = guestSystem;
549 hostSystem = system;
550 }).config.system.build.vm}
551 '';
552 })
553 + /bin/launch-vm;
554 };
555 gomod2nix = {
556 type = "app";
557 program = toString (pkgs.writeShellScript "gomod2nix" ''
558 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
559 '');
560 };
561 lexgen = {
562 type = "app";
563 program =
564 (pkgs.writeShellApplication {
565 name = "lexgen";
566 text = ''
567 if ! command -v lexgen > /dev/null; then
568 echo "error: must be executed from devshell"
569 exit 1
570 fi
571
572 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
573 cd "$rootDir"
574
575 # *_ext.go are hand-written extensions; never remove or mutate them
576 find api/tangled -maxdepth 1 -type f -not -name '*_ext.go' -delete
577 lexgen --build-file lexicon-build-config.json lexicons
578
579 # disable type registration temporarily while running cborgen
580 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -exec \
581 sed -i.bak 's/\tutil/\/\/\tutil/' {} +
582 # lexgen generates incomplete Marshaler/Unmarshaler for union types
583 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -not -name "cbor_gen.go" -exec \
584 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
585 for f in api/tangled/*_ext.go; do [ -e "''$f" ] && mv "''$f" "''$f.bak"; done
586 ${pkgs.gotools}/bin/goimports -w api/tangled/*
587 CGO_ENABLED=0 go run ./cmd/cborgen/
588 for f in api/tangled/*_ext.go.bak; do [ -e "''$f" ] && mv "''$f" "''${f%.bak}"; done
589
590 lexgen --build-file lexicon-build-config.json lexicons
591 rm api/tangled/*.bak
592 '';
593 })
594 + /bin/lexgen;
595 };
596 });
597
598 nixosModules.appview = {
599 lib,
600 pkgs,
601 ...
602 }: {
603 imports = [./nix/modules/appview.nix];
604
605 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
606 };
607 nixosModules.knotmirror = {
608 lib,
609 pkgs,
610 ...
611 }: {
612 imports = [./nix/modules/knotmirror.nix];
613
614 services.tangled.knotmirror.tap-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.tap;
615 services.tangled.knotmirror.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knotmirror;
616 };
617 nixosModules.zoekt-tnglserver = {
618 lib,
619 pkgs,
620 ...
621 }: {
622 imports = [./nix/modules/zoekt-tnglserver.nix];
623
624 services.tangled.zoekt.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-tngl-indexserver;
625 services.tangled.zoekt.zoekt-webserver-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-webserver;
626 };
627 nixosModules.knot = {
628 lib,
629 pkgs,
630 ...
631 }: {
632 imports = [./nix/modules/knot.nix];
633
634 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
635 };
636 nixosModules.spindle = {
637 lib,
638 pkgs,
639 ...
640 }: {
641 imports = [./nix/modules/spindle.nix];
642
643 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
644 };
645 nixosModules.shuttle = {
646 lib,
647 pkgs,
648 ...
649 }: {
650 imports = [./nix/modules/shuttle.nix];
651
652 services.tangled.shuttle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.shuttle;
653 };
654
655 nixosModules.spindle-nixos = import ./nix/microvm/spindle-vm.nix {inherit self microvm;} ./nix/microvm/qemu.nix;
656
657 formatter = forAllSystems (system: self.packages.${system}.treefmt-wrapper);
658
659 nixosConfigurations = let
660 spindleNixosBase = nixpkgs.lib.nixosSystem {
661 system = "x86_64-linux";
662 modules = [self.nixosModules.spindle-nixos];
663 };
664 in {
665 spindle-nixos = spindleNixosBase;
666 };
667 };
668}