alice.pds.demo.boltless.dev
This repository has no description
23 kB
647 lines
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-26.05";
6 microvm = {
7 url = "github:microvm-nix/microvm.nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 fenix = {
11 url = "github:nix-community/fenix";
12 inputs.nixpkgs.follows = "nixpkgs";
13 };
14 gomod2nix = {
15 url = "github:nix-community/gomod2nix";
16 inputs.nixpkgs.follows = "nixpkgs";
17 };
18 flake-compat = {
19 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
20 flake = false;
21 };
22 indigo = {
23 url = "github:oppiliappan/indigo";
24 flake = false;
25 };
26 htmx-src = {
27 url = "https://cdn.jsdelivr.net/npm/htmx.org@2.0.10/dist/htmx.min.js";
28 flake = false;
29 };
30 htmx-ws-src = {
31 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.4";
32 flake = false;
33 };
34 lucide-src = {
35 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
36 flake = false;
37 };
38 inter-fonts-src = {
39 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
40 flake = false;
41 };
42 actor-typeahead-src = {
43 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
44 flake = false;
45 };
46 mermaid-src = {
47 url = "https://cdn.jsdelivr.net/npm/mermaid@11.12.3/dist/mermaid.min.js";
48 flake = false;
49 };
50 hls-src = {
51 url = "https://cdn.jsdelivr.net/npm/hls.js@1.5.13/dist/hls.min.js";
52 flake = false;
53 };
54 mathjax-src = {
55 url = "https://cdn.jsdelivr.net/npm/mathjax@4.1.2/tex-svg.js";
56 flake = false;
57 };
58 tailwindcss-animated-src = {
59 url = "https://registry.npmjs.org/tailwindcss-animated/-/tailwindcss-animated-1.1.2.tgz";
60 flake = false;
61 };
62 ibm-plex-mono-src = {
63 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
64 flake = false;
65 };
66 sqlite-lib-src = {
67 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
68 flake = false;
69 };
70 fetch-tangled = {
71 url = "git+https://tangled.org/isabelroses.com/fetch-tangled";
72 inputs.nixpkgs.follows = "nixpkgs";
73 };
74 };
75
76 outputs = {
77 self,
78 nixpkgs,
79 fenix,
80 gomod2nix,
81 indigo,
82 htmx-src,
83 htmx-ws-src,
84 lucide-src,
85 inter-fonts-src,
86 sqlite-lib-src,
87 ibm-plex-mono-src,
88 actor-typeahead-src,
89 mermaid-src,
90 hls-src,
91 microvm,
92 fetch-tangled,
93 mathjax-src,
94 tailwindcss-animated-src,
95 ...
96 }: let
97 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
98 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
99 nixpkgsFor = forAllSystems (system:
100 import nixpkgs {
101 inherit system;
102 overlays = [fetch-tangled.overlays.default];
103 });
104
105 mkPackageSet = pkgs:
106 pkgs.lib.makeScope pkgs.newScope (self: {
107 src = let
108 fs = pkgs.lib.fileset;
109 in
110 fs.toSource {
111 root = ./.;
112 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
113 };
114 rustSrc = let
115 fs = pkgs.lib.fileset;
116 in
117 fs.toSource {
118 root = ./.;
119 fileset =
120 fs.intersection
121 (fs.fromSource self.src)
122 (fs.unions [
123 ./Cargo.toml
124 ./Cargo.lock
125 ./shuttle
126 ./bobbin
127 ]);
128 };
129 buildGoApplication =
130 (self.callPackage "${gomod2nix}/builder" {
131 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
132 }).buildGoApplication;
133 rustPlatform = pkgs.makeRustPlatform {
134 inherit (fenix.packages.${pkgs.stdenv.hostPlatform.system}.stable) rustc cargo;
135 };
136 rustPlatformStatic = let
137 system = pkgs.stdenv.hostPlatform.system;
138 muslTarget = pkgs.pkgsStatic.stdenv.hostPlatform.rust.rustcTarget;
139 toolchain = fenix.packages.${system}.combine [
140 fenix.packages.${system}.stable.cargo
141 fenix.packages.${system}.stable.rustc
142 fenix.packages.${system}.targets.${muslTarget}.stable.rust-std
143 ];
144 in
145 pkgs.pkgsStatic.makeRustPlatform {
146 cargo = toolchain;
147 rustc = toolchain;
148 };
149 modules = ./nix/gomod2nix.toml;
150 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
151 inherit sqlite-lib-src;
152 };
153 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
154 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
155 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
156 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src mermaid-src hls-src mathjax-src tailwindcss-animated-src;
157 };
158 web-static-files = self.callPackage ./nix/pkgs/web-static-files.nix {
159 inherit inter-fonts-src ibm-plex-mono-src;
160 };
161 appview = self.callPackage ./nix/pkgs/appview.nix {};
162 blog = self.callPackage ./nix/pkgs/blog.nix {};
163 docs = self.callPackage ./nix/pkgs/docs.nix {
164 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
165 inherit (pkgs) pagefind;
166 };
167 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
168 shuttle = self.callPackage ./nix/pkgs/shuttle.nix {
169 src = self.rustSrc;
170 };
171 shuttle-static = self.callPackage ./nix/pkgs/shuttle.nix {
172 src = self.rustSrc;
173 rustPlatform = self.rustPlatformStatic;
174 };
175 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
176 knot = self.callPackage ./nix/pkgs/knot.nix {};
177 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
178 tap = self.callPackage ./nix/pkgs/tap.nix {};
179 knotmirror = self.callPackage ./nix/pkgs/knotmirror.nix {};
180 bobbin = self.callPackage ./nix/pkgs/bobbin.nix {};
181 zoekt-webserver = self.callPackage ./nix/pkgs/zoekt-webserver.nix {};
182 zoekt-tngl-indexserver = self.callPackage ./nix/pkgs/zoekt-tngl-indexserver.nix {};
183 });
184 in {
185 overlays.default = final: prev: {
186 inherit
187 (mkPackageSet final)
188 lexgen
189 goat
190 sqlite-lib
191 spindle
192 shuttle
193 knot-unwrapped
194 knot
195 appview
196 docs
197 dolly
198 tap
199 knotmirror
200 bobbin
201 zoekt-webserver
202 zoekt-tngl-indexserver
203 ;
204 };
205
206 packages = forAllSystems (system: let
207 pkgs = nixpkgsFor.${system};
208 linuxPkgs = nixpkgsFor."x86_64-linux";
209 packages = mkPackageSet pkgs;
210 staticPackages = mkPackageSet pkgs.pkgsStatic;
211 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
212 in {
213 inherit
214 (packages)
215 appview
216 appview-static-files
217 web-static-files
218 blog
219 lexgen
220 goat
221 spindle
222 knot
223 knot-unwrapped
224 sqlite-lib
225 docs
226 shuttle
227 shuttle-static
228 dolly
229 tap
230 knotmirror
231 bobbin
232 zoekt-webserver
233 zoekt-tngl-indexserver
234 ;
235
236 pkgsStatic-appview = staticPackages.appview;
237 pkgsStatic-knot = staticPackages.knot;
238 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
239 pkgsStatic-spindle = staticPackages.spindle;
240 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
241 pkgsStatic-dolly = staticPackages.dolly;
242
243 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
244 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
245 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
246 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
247 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
248
249 treefmt-wrapper = pkgs.treefmt.withConfig {
250 settings.formatter = {
251 alejandra = {
252 command = pkgs.lib.getExe pkgs.alejandra;
253 includes = ["*.nix"];
254 };
255
256 gofmt = {
257 command = pkgs.lib.getExe' pkgs.go "gofmt";
258 options = ["-w"];
259 includes = ["*.go"];
260 };
261
262 rustfmt = {
263 command = pkgs.lib.getExe' fenix.packages.${system}.stable.rustfmt "rustfmt";
264 options = ["--edition" "2024"];
265 includes = ["*.rs"];
266 excludes = ["**/src/_lex/**"];
267 };
268
269 prettier = {
270 command = pkgs.lib.getExe pkgs.prettier;
271 options = ["-w"];
272 includes = [
273 "web/**/*.cjs"
274 "web/**/*.css"
275 "web/**/*.html"
276 "web/**/*.js"
277 "web/**/*.json"
278 "web/**/*.json5"
279 "web/**/*.jsx"
280 "web/**/*.mdx"
281 "web/**/*.mjs"
282 "web/**/*.scss"
283 "web/**/*.ts"
284 "web/**/*.tsx"
285 "web/**/*.vue"
286 "web/**/*.yaml"
287 "web/**/*.yml"
288 ];
289 };
290 };
291 };
292
293 spindle-nixos-image = linuxPkgs.callPackage ./nix/pkgs/spindle-nixos-image.nix {
294 nixosSystem = self.nixosConfigurations.spindle-nixos;
295 };
296 spindle-nixos-image-tarball = linuxPkgs.runCommand "spindle-nixos-image-tarball.tar.gz" {} ''
297 tar -S -C ${self.packages.${system}.spindle-nixos-image} -h -czf $out .
298 '';
299
300 spindle-alpine-image = let
301 branch = "3.24";
302 version = "${branch}.0";
303 arch = "x86_64";
304 cdn = "https://dl-cdn.alpinelinux.org/alpine/v${branch}/releases/${arch}";
305
306 shuttle = (mkPackageSet linuxPkgs).shuttle-static;
307 in
308 linuxPkgs.callPackage ./nix/pkgs/spindle-alpine-image.nix {
309 inherit arch shuttle;
310 repositories = [
311 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/main"
312 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/community"
313 ];
314 rootfs = linuxPkgs.fetchurl {
315 url = "${cdn}/alpine-minirootfs-${version}-${arch}.tar.gz";
316 hash = "sha256-3poRwODn6clNs+2K97RQ6vwLE2h71+kZnVUFDyCqCok=";
317 };
318 kernel = linuxPkgs.fetchurl {
319 url = "${cdn}/netboot-${version}/vmlinuz-virt";
320 hash = "sha256-Hmv5Ancgx1w+0NeRcfIbV5HuQMqXldB8fG4E3F6irpA=";
321 };
322 initramfs = linuxPkgs.fetchurl {
323 url = "${cdn}/netboot-${version}/initramfs-virt";
324 hash = "sha256-ZCWGSaVMOYOmLz1Gwsf2RhYarMqk+tFVA6MMDWiHVJQ=";
325 };
326 modloop = linuxPkgs.fetchurl {
327 url = "${cdn}/netboot-${version}/modloop-virt";
328 hash = "sha256-p3yO7yU28k04iT01sOzhDmEYi+Yl7VZs5r3RYsWCBX0=";
329 };
330 };
331 spindle-alpine-image-tarball = linuxPkgs.runCommand "spindle-alpine-image-tarball.tar.gz" {} ''
332 tar -S -C ${self.packages.${system}.spindle-alpine-image} -h -czf $out .
333 '';
334 });
335 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
336 devShells = forAllSystems (system: let
337 pkgs = nixpkgsFor.${system};
338 packages' = self.packages.${system};
339 tailwindcss-plugins = pkgs.linkFarm "tailwindcss-plugins" [
340 {
341 name = "tailwindcss-animated";
342 path = tailwindcss-animated-src;
343 }
344 ];
345 staticShell = args:
346 (pkgs.mkShell.override {
347 stdenv = pkgs.pkgsStatic.stdenv;
348 }) (args
349 // {
350 nativeBuildInputs =
351 args.nativeBuildInputs
352 ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [
353 pkgs.darwin.cctools
354 ];
355 });
356 in {
357 default = staticShell {
358 nativeBuildInputs =
359 [
360 pkgs.go
361 pkgs.air
362 pkgs.gopls
363 pkgs.httpie
364 pkgs.litecli
365 pkgs.websocat
366 pkgs.tailwindcss
367 pkgs.nixos-shell
368 pkgs.redis
369 pkgs.worker-build
370 pkgs.cargo-generate
371 pkgs.qemu
372 pkgs.cdrkit
373 pkgs.buf
374 pkgs.protobuf
375 pkgs.protoc-gen-prost
376 pkgs.protoc-gen-prost-crate
377 pkgs.protoc-gen-prost-serde
378 pkgs.protoc-gen-go
379 (fenix.packages.${system}.combine [
380 fenix.packages.${system}.stable.cargo
381 fenix.packages.${system}.stable.rustc
382 fenix.packages.${system}.stable.rust-src
383 fenix.packages.${system}.stable.clippy
384 fenix.packages.${system}.stable.rustfmt
385 fenix.packages.${system}.targets.wasm32-unknown-unknown.stable.rust-std
386 ])
387 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
388 packages'.lexgen
389 packages'.treefmt-wrapper
390 packages'.tap
391 pkgs.e2fsprogs
392 pkgs.util-linux
393 pkgs.pnpm
394 ]
395 ++ pkgs.lib.optionals pkgs.stdenv.isLinux [
396 pkgs.parted
397 pkgs.slirp4netns
398 pkgs.iproute2
399 ];
400 shellHook = ''
401 export CC=${pkgs.stdenv.cc}/bin/cc
402 export NODE_PATH=${tailwindcss-plugins}''${NODE_PATH:+:$NODE_PATH}
403 mkdir -p appview/pages/static
404 # temporary self-heal for workspaces that copied static assets as read-only
405 [ -d appview/pages/static/icons ] && [ ! -w appview/pages/static/icons ] && chmod -R u+rwX appview/pages/static
406 # no preserve is needed because watch-tailwind will want to be able to overwrite
407 cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
408 mkdir -p web/static
409 rm -rf web/static/fonts web/static/logos
410 cp -fr --no-preserve=ownership,mode ${packages'.web-static-files}/* web/static
411 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
412 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
413 # Make xcrun (Nix stub) able to find ld from the system Command Line Tools.
414 # Without this, worker-build/cargo fails with "error: tool 'ld' not found".
415 if [ -d /Library/Developer/CommandLineTools/usr/bin ]; then
416 export PATH=/Library/Developer/CommandLineTools/usr/bin:$PATH
417 fi
418 '';
419 env.CGO_ENABLED = 1;
420 };
421 });
422 apps = forAllSystems (system: let
423 pkgs = nixpkgsFor."${system}";
424 packages' = self.packages.${system};
425 tailwindcss-plugins = pkgs.linkFarm "tailwindcss-plugins" [
426 {
427 name = "tailwindcss-animated";
428 path = tailwindcss-animated-src;
429 }
430 ];
431 air-watcher = name: arg:
432 pkgs.writeShellScriptBin "run"
433 ''
434 export PATH=${pkgs.go}/bin:$PATH
435 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
436 -build.args_bin "${arg}"
437 '';
438 tailwind-watcher =
439 pkgs.writeShellScriptBin "run"
440 ''
441 export BROWSERSLIST_IGNORE_OLD_DATA=true
442 export NODE_PATH=${tailwindcss-plugins}
443 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
444 '';
445 in {
446 watch-appview = {
447 type = "app";
448 program = toString (pkgs.writeShellScript "watch-appview" ''
449 echo "copying static files to appview/pages/static..."
450 mkdir -p appview/pages/static
451 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
452 ${air-watcher "appview" ""}/bin/run
453 '');
454 };
455 watch-knot = {
456 type = "app";
457 program = ''${air-watcher "knot" "server"}/bin/run'';
458 };
459 watch-spindle = {
460 type = "app";
461 program = ''${air-watcher "spindle" ""}/bin/run'';
462 };
463 watch-blog = {
464 type = "app";
465 program = toString (pkgs.writeShellScript "watch-blog" ''
466 echo "copying static files to appview/pages/static..."
467 mkdir -p appview/pages/static
468 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
469 ${air-watcher "blog" "serve"}/bin/run
470 '');
471 };
472 watch-tailwind = {
473 type = "app";
474 program = ''${tailwind-watcher}/bin/run'';
475 };
476 serve-docs = {
477 type = "app";
478 program = toString (pkgs.writeShellScript "serve-docs" ''
479 echo "building docs..."
480 docsOut=$(nix build --no-link --print-out-paths .#docs)
481 echo "serving docs at http://localhost:1414"
482 cd "$docsOut"
483 exec ${pkgs.python3}/bin/python3 -m http.server 1414
484 '');
485 };
486 regenerate-proto = {
487 type = "app";
488 program =
489 (pkgs.writeShellApplication {
490 name = "regenerate-proto";
491 runtimeInputs = with pkgs; [git buf coreutils];
492 text = ''
493 rootDir=$(git rev-parse --show-toplevel 2>/dev/null || pwd)
494 cd "$rootDir"
495 echo ">>> regenerating protobuf files.."
496 buf generate
497 echo ">>> generating file descriptor set for shuttle..."
498 buf build -o shuttle/src/gen/file_descriptor_set.bin
499 echo ">>> done"
500 '';
501 })
502 + "/bin/regenerate-proto";
503 };
504 vm = let
505 guestSystem =
506 if pkgs.stdenv.hostPlatform.isAarch64
507 then "aarch64-linux"
508 else "x86_64-linux";
509 in {
510 type = "app";
511 program =
512 (pkgs.writeShellApplication {
513 name = "launch-vm";
514 text = ''
515 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
516 cd "$rootDir"
517
518 # Reset TMPDIR in case it points to a stale nix-shell temp dir
519 export TMPDIR=/tmp
520
521 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
522
523 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
524 exec ${pkgs.lib.getExe
525 (import ./nix/vm.nix {
526 inherit nixpkgs self;
527 system = guestSystem;
528 hostSystem = system;
529 }).config.system.build.vm}
530 '';
531 })
532 + /bin/launch-vm;
533 };
534 gomod2nix = {
535 type = "app";
536 program = toString (pkgs.writeShellScript "gomod2nix" ''
537 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
538 '');
539 };
540 lexgen = {
541 type = "app";
542 program =
543 (pkgs.writeShellApplication {
544 name = "lexgen";
545 text = ''
546 if ! command -v lexgen > /dev/null; then
547 echo "error: must be executed from devshell"
548 exit 1
549 fi
550
551 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
552 cd "$rootDir"
553
554 # *_ext.go are hand-written extensions; never remove or mutate them
555 find api/tangled -maxdepth 1 -type f -not -name '*_ext.go' -delete
556 lexgen --build-file lexicon-build-config.json lexicons
557
558 # disable type registration temporarily while running cborgen
559 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -exec \
560 sed -i.bak 's/\tutil/\/\/\tutil/' {} +
561 # lexgen generates incomplete Marshaler/Unmarshaler for union types
562 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -not -name "cbor_gen.go" -exec \
563 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
564 for f in api/tangled/*_ext.go; do [ -e "''$f" ] && mv "''$f" "''$f.bak"; done
565 ${pkgs.gotools}/bin/goimports -w api/tangled/*
566 CGO_ENABLED=0 go run ./cmd/cborgen/
567 for f in api/tangled/*_ext.go.bak; do [ -e "''$f" ] && mv "''$f" "''${f%.bak}"; done
568
569 lexgen --build-file lexicon-build-config.json lexicons
570 rm api/tangled/*.bak
571 '';
572 })
573 + /bin/lexgen;
574 };
575 });
576
577 nixosModules.appview = {
578 lib,
579 pkgs,
580 ...
581 }: {
582 imports = [./nix/modules/appview.nix];
583
584 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
585 };
586 nixosModules.knotmirror = {
587 lib,
588 pkgs,
589 ...
590 }: {
591 imports = [./nix/modules/knotmirror.nix];
592
593 services.tangled.knotmirror.tap-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.tap;
594 services.tangled.knotmirror.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knotmirror;
595 };
596 nixosModules.zoekt-tnglserver = {
597 lib,
598 pkgs,
599 ...
600 }: {
601 imports = [./nix/modules/zoekt-tnglserver.nix];
602
603 services.tangled.zoekt.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-tngl-indexserver;
604 services.tangled.zoekt.zoekt-webserver-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-webserver;
605 };
606 nixosModules.knot = {
607 lib,
608 pkgs,
609 ...
610 }: {
611 imports = [./nix/modules/knot.nix];
612
613 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
614 };
615 nixosModules.spindle = {
616 lib,
617 pkgs,
618 ...
619 }: {
620 imports = [./nix/modules/spindle.nix];
621
622 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
623 };
624 nixosModules.shuttle = {
625 lib,
626 pkgs,
627 ...
628 }: {
629 imports = [./nix/modules/shuttle.nix];
630
631 services.tangled.shuttle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.shuttle;
632 };
633
634 nixosModules.spindle-nixos = import ./nix/microvm/spindle-vm.nix {inherit self microvm;} ./nix/microvm/qemu.nix;
635
636 formatter = forAllSystems (system: self.packages.${system}.treefmt-wrapper);
637
638 nixosConfigurations = let
639 spindleNixosBase = nixpkgs.lib.nixosSystem {
640 system = "x86_64-linux";
641 modules = [self.nixosModules.spindle-nixos];
642 };
643 in {
644 spindle-nixos = spindleNixosBase;
645 };
646 };
647}