alice.pds.demo.boltless.dev
This repository has no description
24 kB
661 lines
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-26.05";
6 microvm = {
7 url = "github:microvm-nix/microvm.nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 fenix = {
11 url = "github:nix-community/fenix";
12 inputs.nixpkgs.follows = "nixpkgs";
13 };
14 gomod2nix = {
15 url = "github:nix-community/gomod2nix";
16 inputs.nixpkgs.follows = "nixpkgs";
17 };
18 flake-compat = {
19 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
20 flake = false;
21 };
22 indigo = {
23 url = "github:oppiliappan/indigo";
24 flake = false;
25 };
26 htmx-src = {
27 url = "https://cdn.jsdelivr.net/npm/htmx.org@2.0.10/dist/htmx.min.js";
28 flake = false;
29 };
30 htmx-ws-src = {
31 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.4";
32 flake = false;
33 };
34 lucide-src = {
35 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
36 flake = false;
37 };
38 inter-fonts-src = {
39 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
40 flake = false;
41 };
42 actor-typeahead-src = {
43 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
44 flake = false;
45 };
46 mermaid-src = {
47 url = "https://cdn.jsdelivr.net/npm/mermaid@11.12.3/dist/mermaid.min.js";
48 flake = false;
49 };
50 hls-src = {
51 url = "https://cdn.jsdelivr.net/npm/hls.js@1.5.13/dist/hls.min.js";
52 flake = false;
53 };
54 mathjax-src = {
55 url = "https://cdn.jsdelivr.net/npm/mathjax@4.1.2/tex-svg.js";
56 flake = false;
57 };
58 tailwindcss-animated-src = {
59 url = "https://registry.npmjs.org/tailwindcss-animated/-/tailwindcss-animated-1.1.2.tgz";
60 flake = false;
61 };
62 ibm-plex-mono-src = {
63 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
64 flake = false;
65 };
66 sqlite-lib-src = {
67 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
68 flake = false;
69 };
70 fetch-tangled = {
71 url = "git+https://tangled.org/isabelroses.com/fetch-tangled";
72 inputs.nixpkgs.follows = "nixpkgs";
73 };
74 };
75
76 outputs = {
77 self,
78 nixpkgs,
79 fenix,
80 gomod2nix,
81 indigo,
82 htmx-src,
83 htmx-ws-src,
84 lucide-src,
85 inter-fonts-src,
86 sqlite-lib-src,
87 ibm-plex-mono-src,
88 actor-typeahead-src,
89 mermaid-src,
90 hls-src,
91 microvm,
92 fetch-tangled,
93 mathjax-src,
94 tailwindcss-animated-src,
95 ...
96 }: let
97 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
98 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
99 nixpkgsFor = forAllSystems (system:
100 import nixpkgs {
101 inherit system;
102 overlays = [fetch-tangled.overlays.default];
103 });
104
105 mkPackageSet = pkgs:
106 pkgs.lib.makeScope pkgs.newScope (self: {
107 src = let
108 fs = pkgs.lib.fileset;
109 in
110 fs.toSource {
111 root = ./.;
112 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
113 };
114 rustSrc = let
115 fs = pkgs.lib.fileset;
116 in
117 fs.toSource {
118 root = ./.;
119 fileset =
120 fs.intersection
121 (fs.fromSource self.src)
122 (fs.unions [
123 ./Cargo.toml
124 ./Cargo.lock
125 ./lexicons
126 ./shuttle
127 ./bobbin
128 ./knot2
129 ]);
130 };
131 buildGoApplication =
132 (self.callPackage "${gomod2nix}/builder" {
133 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
134 }).buildGoApplication;
135 rustPlatform = pkgs.makeRustPlatform {
136 inherit (fenix.packages.${pkgs.stdenv.hostPlatform.system}.stable) rustc cargo;
137 };
138 rustPlatformStatic = let
139 system = pkgs.stdenv.hostPlatform.system;
140 muslTarget = pkgs.pkgsStatic.stdenv.hostPlatform.rust.rustcTarget;
141 toolchain = fenix.packages.${system}.combine [
142 fenix.packages.${system}.stable.cargo
143 fenix.packages.${system}.stable.rustc
144 fenix.packages.${system}.targets.${muslTarget}.stable.rust-std
145 ];
146 in
147 pkgs.pkgsStatic.makeRustPlatform {
148 cargo = toolchain;
149 rustc = toolchain;
150 };
151 modules = ./nix/gomod2nix.toml;
152 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
153 inherit sqlite-lib-src;
154 };
155 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
156 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
157 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
158 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src mermaid-src hls-src mathjax-src tailwindcss-animated-src;
159 };
160 web-static-files = self.callPackage ./nix/pkgs/web-static-files.nix {
161 inherit inter-fonts-src ibm-plex-mono-src;
162 };
163 appview = self.callPackage ./nix/pkgs/appview.nix {};
164 blog = self.callPackage ./nix/pkgs/blog.nix {};
165 docs = self.callPackage ./nix/pkgs/docs.nix {
166 inherit inter-fonts-src ibm-plex-mono-src lucide-src tailwindcss-animated-src;
167 inherit (pkgs) pagefind;
168 };
169 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
170 shuttle = self.callPackage ./nix/pkgs/shuttle.nix {
171 src = self.rustSrc;
172 };
173 shuttle-static = self.callPackage ./nix/pkgs/shuttle.nix {
174 src = self.rustSrc;
175 rustPlatform = self.rustPlatformStatic;
176 };
177 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
178 knot = self.callPackage ./nix/pkgs/knot.nix {};
179 knot-rs = self.callPackage ./nix/pkgs/knot-crate.nix {
180 src = self.rustSrc;
181 crate = "knot-server";
182 };
183 knot-migrate = self.callPackage ./nix/pkgs/knot-crate.nix {
184 src = self.rustSrc;
185 crate = "knot-migrate";
186 };
187 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
188 tap = self.callPackage ./nix/pkgs/tap.nix {};
189 knotmirror = self.callPackage ./nix/pkgs/knotmirror.nix {};
190 bobbin = self.callPackage ./nix/pkgs/bobbin.nix {};
191 zoekt-webserver = self.callPackage ./nix/pkgs/zoekt-webserver.nix {};
192 zoekt-tngl-indexserver = self.callPackage ./nix/pkgs/zoekt-tngl-indexserver.nix {};
193 });
194 in {
195 overlays.default = final: prev: {
196 inherit
197 (mkPackageSet final)
198 lexgen
199 goat
200 sqlite-lib
201 spindle
202 shuttle
203 knot-unwrapped
204 knot
205 knot-rs
206 knot-migrate
207 appview
208 docs
209 dolly
210 tap
211 knotmirror
212 bobbin
213 zoekt-webserver
214 zoekt-tngl-indexserver
215 ;
216 };
217
218 packages = forAllSystems (system: let
219 pkgs = nixpkgsFor.${system};
220 linuxPkgs = nixpkgsFor."x86_64-linux";
221 packages = mkPackageSet pkgs;
222 staticPackages = mkPackageSet pkgs.pkgsStatic;
223 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
224 in {
225 inherit
226 (packages)
227 appview
228 appview-static-files
229 web-static-files
230 blog
231 lexgen
232 goat
233 spindle
234 knot
235 knot-unwrapped
236 knot-rs
237 knot-migrate
238 sqlite-lib
239 docs
240 shuttle
241 shuttle-static
242 dolly
243 tap
244 knotmirror
245 bobbin
246 zoekt-webserver
247 zoekt-tngl-indexserver
248 ;
249
250 pkgsStatic-appview = staticPackages.appview;
251 pkgsStatic-knot = staticPackages.knot;
252 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
253 pkgsStatic-spindle = staticPackages.spindle;
254 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
255 pkgsStatic-dolly = staticPackages.dolly;
256
257 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
258 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
259 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
260 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
261 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
262
263 treefmt-wrapper = pkgs.treefmt.withConfig {
264 settings.formatter = {
265 alejandra = {
266 command = pkgs.lib.getExe pkgs.alejandra;
267 includes = ["*.nix"];
268 };
269
270 gofmt = {
271 command = pkgs.lib.getExe' pkgs.go "gofmt";
272 options = ["-w"];
273 includes = ["*.go"];
274 };
275
276 rustfmt = {
277 command = pkgs.lib.getExe' fenix.packages.${system}.stable.rustfmt "rustfmt";
278 options = ["--edition" "2024"];
279 includes = ["*.rs"];
280 excludes = ["**/src/_lex/**"];
281 };
282
283 # prettier = let
284 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
285 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
286 # '';
287 # in {
288 # command = wrapper;
289 # options = ["-w"];
290 # includes = ["*.html"];
291 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
292 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
293 # };
294 };
295 };
296
297 spindle-nixos-image = linuxPkgs.callPackage ./nix/pkgs/spindle-nixos-image.nix {
298 nixosSystem = self.nixosConfigurations.spindle-nixos;
299 };
300 spindle-nixos-image-tarball = linuxPkgs.runCommand "spindle-nixos-image-tarball.tar.gz" {} ''
301 tar -S -C ${self.packages.${system}.spindle-nixos-image} -h -czf $out .
302 '';
303
304 spindle-alpine-image = let
305 branch = "3.24";
306 version = "${branch}.0";
307 arch = "x86_64";
308 cdn = "https://dl-cdn.alpinelinux.org/alpine/v${branch}/releases/${arch}";
309
310 shuttle = (mkPackageSet linuxPkgs).shuttle-static;
311 in
312 linuxPkgs.callPackage ./nix/pkgs/spindle-alpine-image.nix {
313 inherit arch shuttle;
314 repositories = [
315 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/main"
316 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/community"
317 ];
318 rootfs = linuxPkgs.fetchurl {
319 url = "${cdn}/alpine-minirootfs-${version}-${arch}.tar.gz";
320 hash = "sha256-3poRwODn6clNs+2K97RQ6vwLE2h71+kZnVUFDyCqCok=";
321 };
322 kernel = linuxPkgs.fetchurl {
323 url = "${cdn}/netboot-${version}/vmlinuz-virt";
324 hash = "sha256-Hmv5Ancgx1w+0NeRcfIbV5HuQMqXldB8fG4E3F6irpA=";
325 };
326 initramfs = linuxPkgs.fetchurl {
327 url = "${cdn}/netboot-${version}/initramfs-virt";
328 hash = "sha256-ZCWGSaVMOYOmLz1Gwsf2RhYarMqk+tFVA6MMDWiHVJQ=";
329 };
330 modloop = linuxPkgs.fetchurl {
331 url = "${cdn}/netboot-${version}/modloop-virt";
332 hash = "sha256-p3yO7yU28k04iT01sOzhDmEYi+Yl7VZs5r3RYsWCBX0=";
333 };
334 };
335 spindle-alpine-image-tarball = linuxPkgs.runCommand "spindle-alpine-image-tarball.tar.gz" {} ''
336 tar -S -C ${self.packages.${system}.spindle-alpine-image} -h -czf $out .
337 '';
338 });
339 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
340 devShells = forAllSystems (system: let
341 pkgs = nixpkgsFor.${system};
342 packages' = self.packages.${system};
343 tailwindcss-plugins = pkgs.linkFarm "tailwindcss-plugins" [
344 {
345 name = "tailwindcss-animated";
346 path = tailwindcss-animated-src;
347 }
348 ];
349 staticShell = args:
350 (pkgs.mkShell.override {
351 stdenv = pkgs.pkgsStatic.stdenv;
352 }) (args
353 // {
354 nativeBuildInputs =
355 args.nativeBuildInputs
356 ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [
357 pkgs.darwin.cctools
358 ];
359 });
360 in {
361 default = staticShell {
362 nativeBuildInputs =
363 [
364 pkgs.go
365 pkgs.air
366 pkgs.gopls
367 pkgs.httpie
368 pkgs.litecli
369 pkgs.websocat
370 pkgs.tailwindcss
371 pkgs.nixos-shell
372 pkgs.redis
373 pkgs.worker-build
374 pkgs.cargo-generate
375 pkgs.qemu
376 pkgs.cdrkit
377 pkgs.buf
378 pkgs.protobuf
379 pkgs.protoc-gen-prost
380 pkgs.protoc-gen-prost-crate
381 pkgs.protoc-gen-prost-serde
382 pkgs.protoc-gen-go
383 (fenix.packages.${system}.combine [
384 fenix.packages.${system}.stable.cargo
385 fenix.packages.${system}.stable.rustc
386 fenix.packages.${system}.stable.rust-src
387 fenix.packages.${system}.stable.clippy
388 fenix.packages.${system}.stable.rustfmt
389 fenix.packages.${system}.targets.wasm32-unknown-unknown.stable.rust-std
390 ])
391 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
392 packages'.lexgen
393 packages'.treefmt-wrapper
394 packages'.tap
395 pkgs.e2fsprogs
396 pkgs.util-linux
397 pkgs.pnpm
398 ]
399 ++ pkgs.lib.optionals pkgs.stdenv.isLinux [
400 pkgs.parted
401 pkgs.slirp4netns
402 pkgs.iproute2
403 ];
404 shellHook = ''
405 export CC=${pkgs.stdenv.cc}/bin/cc
406 export NODE_PATH=${tailwindcss-plugins}''${NODE_PATH:+:$NODE_PATH}
407 mkdir -p appview/pages/static
408 # temporary self-heal for workspaces that copied static assets as read-only
409 [ -d appview/pages/static/icons ] && [ ! -w appview/pages/static/icons ] && chmod -R u+rwX appview/pages/static
410 # no preserve is needed because watch-tailwind will want to be able to overwrite
411 cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
412 mkdir -p web/static
413 rm -rf web/static/fonts web/static/logos
414 cp -fr --no-preserve=ownership,mode ${packages'.web-static-files}/* web/static
415 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
416 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
417 # Make xcrun (Nix stub) able to find ld from the system Command Line Tools.
418 # Without this, worker-build/cargo fails with "error: tool 'ld' not found".
419 if [ -d /Library/Developer/CommandLineTools/usr/bin ]; then
420 export PATH=/Library/Developer/CommandLineTools/usr/bin:$PATH
421 fi
422 '';
423 env.CGO_ENABLED = 1;
424 };
425 });
426 apps = forAllSystems (system: let
427 pkgs = nixpkgsFor."${system}";
428 packages' = self.packages.${system};
429 tailwindcss-plugins = pkgs.linkFarm "tailwindcss-plugins" [
430 {
431 name = "tailwindcss-animated";
432 path = tailwindcss-animated-src;
433 }
434 ];
435 air-watcher = name: arg:
436 pkgs.writeShellScriptBin "run"
437 ''
438 export PATH=${pkgs.go}/bin:$PATH
439 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
440 -build.args_bin "${arg}"
441 '';
442 tailwind-watcher =
443 pkgs.writeShellScriptBin "run"
444 ''
445 export BROWSERSLIST_IGNORE_OLD_DATA=true
446 export NODE_PATH=${tailwindcss-plugins}
447 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
448 '';
449 in {
450 watch-appview = {
451 type = "app";
452 program = toString (pkgs.writeShellScript "watch-appview" ''
453 echo "copying static files to appview/pages/static..."
454 mkdir -p appview/pages/static
455 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
456 ${air-watcher "appview" ""}/bin/run
457 '');
458 };
459 watch-knot = {
460 type = "app";
461 program = ''${air-watcher "knot" "server"}/bin/run'';
462 };
463 watch-spindle = {
464 type = "app";
465 program = ''${air-watcher "spindle" ""}/bin/run'';
466 };
467 watch-blog = {
468 type = "app";
469 program = toString (pkgs.writeShellScript "watch-blog" ''
470 echo "copying static files to appview/pages/static..."
471 mkdir -p appview/pages/static
472 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
473 ${air-watcher "blog" "serve"}/bin/run
474 '');
475 };
476 watch-tailwind = {
477 type = "app";
478 program = ''${tailwind-watcher}/bin/run'';
479 };
480 serve-docs = {
481 type = "app";
482 program = toString (pkgs.writeShellScript "serve-docs" ''
483 echo "building docs..."
484 docsOut=$(nix build --no-link --print-out-paths .#docs)
485 echo "serving docs at http://localhost:1414"
486 cd "$docsOut"
487 exec ${pkgs.python3}/bin/python3 -m http.server 1414
488 '');
489 };
490 regenerate-proto = {
491 type = "app";
492 program =
493 (pkgs.writeShellApplication {
494 name = "regenerate-proto";
495 runtimeInputs = with pkgs; [git buf coreutils];
496 text = ''
497 rootDir=$(git rev-parse --show-toplevel 2>/dev/null || pwd)
498 cd "$rootDir"
499 echo ">>> regenerating protobuf files.."
500 buf generate
501 echo ">>> generating file descriptor set for shuttle..."
502 buf build -o shuttle/src/gen/file_descriptor_set.bin
503 echo ">>> done"
504 '';
505 })
506 + "/bin/regenerate-proto";
507 };
508 vm = let
509 guestSystem =
510 if pkgs.stdenv.hostPlatform.isAarch64
511 then "aarch64-linux"
512 else "x86_64-linux";
513 in {
514 type = "app";
515 program =
516 (pkgs.writeShellApplication {
517 name = "launch-vm";
518 text = ''
519 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
520 cd "$rootDir"
521
522 # Reset TMPDIR in case it points to a stale nix-shell temp dir
523 export TMPDIR=/tmp
524
525 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
526
527 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
528 exec ${pkgs.lib.getExe
529 (import ./nix/vm.nix {
530 inherit nixpkgs self;
531 system = guestSystem;
532 hostSystem = system;
533 }).config.system.build.vm}
534 '';
535 })
536 + /bin/launch-vm;
537 };
538 gomod2nix = {
539 type = "app";
540 program = toString (pkgs.writeShellScript "gomod2nix" ''
541 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
542 '');
543 };
544 lexgen = {
545 type = "app";
546 program =
547 (pkgs.writeShellApplication {
548 name = "lexgen";
549 text = ''
550 if ! command -v lexgen > /dev/null; then
551 echo "error: must be executed from devshell"
552 exit 1
553 fi
554
555 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
556 cd "$rootDir"
557
558 # *_ext.go are hand-written extensions; never remove or mutate them
559 find api/tangled -maxdepth 1 -type f -not -name '*_ext.go' -delete
560 lexgen --build-file lexicon-build-config.json lexicons
561
562 # disable type registration temporarily while running cborgen
563 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -exec \
564 sed -i.bak 's/\tutil/\/\/\tutil/' {} +
565 # lexgen generates incomplete Marshaler/Unmarshaler for union types
566 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -not -name "cbor_gen.go" -exec \
567 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
568 for f in api/tangled/*_ext.go; do [ -e "''$f" ] && mv "''$f" "''$f.bak"; done
569 ${pkgs.gotools}/bin/goimports -w api/tangled/*
570 CGO_ENABLED=0 go run ./cmd/cborgen/
571 for f in api/tangled/*_ext.go.bak; do [ -e "''$f" ] && mv "''$f" "''${f%.bak}"; done
572
573 lexgen --build-file lexicon-build-config.json lexicons
574 rm api/tangled/*.bak
575 '';
576 })
577 + /bin/lexgen;
578 };
579 });
580
581 nixosModules.appview = {
582 lib,
583 pkgs,
584 ...
585 }: {
586 imports = [./nix/modules/appview.nix];
587
588 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
589 };
590 nixosModules.knotmirror = {
591 lib,
592 pkgs,
593 ...
594 }: {
595 imports = [./nix/modules/knotmirror.nix];
596
597 services.tangled.knotmirror.tap-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.tap;
598 services.tangled.knotmirror.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knotmirror;
599 };
600 nixosModules.zoekt-tnglserver = {
601 lib,
602 pkgs,
603 ...
604 }: {
605 imports = [./nix/modules/zoekt-tnglserver.nix];
606
607 services.tangled.zoekt.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-tngl-indexserver;
608 services.tangled.zoekt.zoekt-webserver-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-webserver;
609 };
610 nixosModules.knot = {
611 lib,
612 pkgs,
613 ...
614 }: {
615 imports = [./nix/modules/knot.nix];
616
617 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
618 };
619 nixosModules.knot-rs = {
620 lib,
621 pkgs,
622 ...
623 }: {
624 imports = [./nix/modules/knot-rs.nix];
625
626 services.tangled.knot-rs.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot-rs;
627 services.tangled.knot-rs.migratePackage = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot-migrate;
628 };
629 nixosModules.spindle = {
630 lib,
631 pkgs,
632 ...
633 }: {
634 imports = [./nix/modules/spindle.nix];
635
636 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
637 };
638 nixosModules.shuttle = {
639 lib,
640 pkgs,
641 ...
642 }: {
643 imports = [./nix/modules/shuttle.nix];
644
645 services.tangled.shuttle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.shuttle;
646 };
647
648 nixosModules.spindle-nixos = import ./nix/microvm/spindle-vm.nix {inherit self microvm;} ./nix/microvm/qemu.nix;
649
650 formatter = forAllSystems (system: self.packages.${system}.treefmt-wrapper);
651
652 nixosConfigurations = let
653 spindleNixosBase = nixpkgs.lib.nixosSystem {
654 system = "x86_64-linux";
655 modules = [self.nixosModules.spindle-nixos];
656 };
657 in {
658 spindle-nixos = spindleNixosBase;
659 };
660 };
661}